5 CLEAR300:REM DEFINTA-y

10 SCREEN1,2:WIDTH32:KEYOFF:COLOR1,14,14:PF=3:PP=9:MN=900:RN=0:ES=0

11 DIMSX(19),SY(19),SC(19),T1(9),T2(9),T3(9),M1(9),M2(9),M3(9),D1(9),D2(9),D3(9),P1(9),P2(9),P3(9),DI(9),Z1(9),Z2(9),RP(9)

12 DIMRC$(9)

13 A=1:FORI=0TO9:T1(I)=A:A=A+1:T2(I)=A:A=A+1:T3(I)=A:A=A+1:NEXT

14 RP(0)=6:RP(1)=5:RP(2)=4:RP(3)=3:RP(4)=2:RP(5)=1

15 DATA0.8,1.2,1.5,0.5,0.8,1.2,0.5,1.5,1.3,0.7,0.7,1.3,1.2,0.8,1.5,0.5,0.9,1.1,0.8,1.2:RESTORE15:FORI=0TO9:READA,B:Z1(I)=A:Z2(I)=B:NEXT

16 GOSUB1100:ONINTERVAL=117GOSUB1000:INTERVALON

17 DATA"AUSTRALIA","CHINA","SPAIN","MONACO","GREAT BRITAIN","GERMANY","BELGIUM","ITALY","JAPAN","BRAZIL":RESTORE17:FORI=0TO9:READRC$(I):NEXT

19 DATA 255,255,255,60,60,255,255,255

20 DATA 65,66,67,68,97,129,161,162,164,165,166,168,169,170,172,176,178,180,182,186,187,188,193,196,198,200,202,204,205,207,208,210,212,214,218,220

30 DATA 225,228,230,232,233,236,238,240,242,244,246,250,251,252,257,260,262,264,266,268,272,274,276,278,282,284

40 DATA 289,292,293,294,296,298,300,304,306,307,308,310,311,312,314,316

50 DATA 401,402,403,406,408,409,410,412,413,414,433,436,438,440,444

60 DATA 465,468,470,472,476,477,497,500,502,504,508,529,532,534,536,540,561,562,563,566,568,569,570,572,573,574,0

70 FORI=0TO7:VPOKEBASE(12)+1600+I,255:NEXT

71 FORI=0TO7:READA:VPOKEBASE(12)+1608+I,A:NEXT

80 READA:IFA=0THENGOTO101

90 VPOKEBASE(10)+A,200

100 GOTO 80

101 GOSUB 50000

110 FORI=13TO1STEP-1:VPOKEBASE(11)+25,I*16:FORU=1TO100:NEXTU:NEXTI

111 A$="a game by ROBYLU"

112 FORI=1TOLEN(A$):LOCATE2,21:PRINTLEFT$(A$,I):FORU=1TO50:NEXTU:NEXTI

113 LOCATE 2,22:PRINT"PRESS SPACE BAR"

120 FORI=13TO1STEP-1:VPOKEBASE(11)+25,I*16:FORU=1TO100:NEXTU:A$=INKEY$:IFA$<>""THEN130

121 NEXTI:GOTO120

130 COLOR 1,14,14:CLS:PRINT"THE GOAL OF THIS GAME IS TO":PRINT"TO WIN THE FORMULA 1. YOU":PRINT"START ON FORMULA 3 AND YOU":PRINT"HAVE TO REACH THE TOP 2":PRINT"POSITION TO BE PROMOTED."

140 PRINT"TO DO THIS YOU CAN BUY POINTS":PRINT"(MOTOR AND DRIVER) TO ADD TO":PRINT"YOUR TEAM. THESE POINTS ADDED":PRINT"TO A RANDOM DICE WILL MOVE YOUR":PRINT"CAR IN THE RACE. 10 ROUNDS"

141 PRINT"WILL BE RACED. BEFORE EACH":PRINT"SEASON YOU HAVE TO PAY AN":PRINT"INSCRIPTION TAX (100 FOR F3":PRINT"200 FOR F2 AND 300 FOR F1)":PRINT"SO WATCH OUT YOUR BUDGET!"

150 PRINT"ENJOY THIS LITTLE GAME!!":PRINT:PRINT"PRESS ANY KEY"

160 A$=INKEY$:IFA$=""THENGOTO160

170 LOCATE0,20:PRINT"ENTER YOUR CAR NUMBER (30-99) ":INPUTCN:IFCN>29ANDCN<100THENT3(9)=CNELSEGOTO170

180 CLS:LOCATE 3,0:PRINT"SELECT THE LEVEL:":LOCATE0,2:PRINT"1) EASY LEVEL":LOCATE3,3:PRINT"(ALL COMPUTER TEAMS START":LOCATE3,4:PRINT"WITH 2 MOTOR POINTS":LOCATE3,5:PRINT"AND 2 DRIVER POINTS)"

190 LOCATE0,7:PRINT"2) NORMAL LEVEL":LOCATE3,8:PRINT"(F1 TEAMS WITH 12 MOTOR":LOCATE3,9:PRINT"AND DRIVER POINTS":LOCATE3,10:PRINT"F2 TEAMS WITH 7 DRIVER AND":LOCATE3,11:PRINT"MOTOR POINTS"

200 LOCATE3,12:PRINT"F3 TEAMS WITH 2 DRIVER AND":LOCATE3,13:PRINT"MOTOR POINTS)":LOCATE0,15:PRINT"3) HARD LEVEL":LOCATE3,16:PRINT"(F1 TEAMS WITH 20 DRIVER":LOCATE3,17:PRINT"AND MOTOR POINTS"

210 LOCATE3,18:PRINT"F2 TEAMS WITH 12 DRIVER AND":LOCATE3,19:PRINT"MOTOR POINTS":LOCATE3,20:PRINT"F3 TEAMS WITH 4 DRIVER AND":LOCATE3,21:PRINT"MOTOR POINTS)"

220 LOCATE 3,24:PRINT"MAKE YOUR CHOICE ";

230 A$=INKEY$:IF A$=""THENGOTO230

240 LV=VAL(A$):IFLV<1ANDLV>3THEN230

250 ONLVGOTO260,300,350

260 FORI=0TO9:M1(I)=2:D1(I)=2:M2(I)=2:D2(I)=2:M3(I)=2:D3(I)=2:NEXT:D3(9)=0:M3(9)=0:GOTO990

300 FORI=0TO9:M1(I)=12:D1(I)=12:M2(I)=7:D2(I)=7:M3(I)=2:D3(I)=2:NEXT:D3(9)=0:M3(9)=0:GOTO990

350 FORI=0TO9:M1(I)=20:D1(I)=20:M2(I)=12:D2(I)=12:M3(I)=4:D3(I)=4:NEXT:D3(9)=0:M3(9)=0

990 GOTO 5000

1000 REM music

1001 MU=MU+1:IFMU=17THENMU=1

1010 ONMUGOTO1110,1120,1130,1140,1150,1160,1170,1180,1190,1200,1210,1220,1230,1240,1250,1260

1100 PLAY"t130s1m10000","s1m20000":RETURN

1110 PLAY"o5e8d8o4a2.","o2a1":GOTO1270

1120 PLAY"b2g2","g1":GOTO1270

1130 PLAY"o5a4.f8a4f8a8","f1":GOTO1270

1140 PLAY"a2g+2","e1":GOTO1270

1150 PLAY"c16o4b16a2.r64a8...","a1":GOTO1270

1160 PLAY"g8a8b8o5c8d2","g1":GOTO1270

1170 PLAY"g8o6e8.r16e4.d4","c1":GOTO1270

1180 PLAY"o5b4a4g+2","e1":GOTO1270

1190 PLAY"e8.r16e8.r16e8d8o4a4","a1":GOTO1270

1200 PLAY"b4.o5c8o4b2","g1":GOTO1270

1210 PLAY"o5f8.e16d+8r16d16c4.d8","f1":GOTO1270

1220 PLAY"e8o4b16o5e16o4b16o5e16o4b16o5e16o4b2","e1":GOTO1270

1230 PLAY"o5c8o4a2o5e8d8c8","a1":GOTO1270

1240 PLAY"d2o4b2","g1":GOTO1270

1250 PLAY"o5g16f16e16d16e4g16f16e16d16e4","c1":GOTO1270

1260 PLAY"g+16f16e16d16e4g+16f16e16d16e4","e1":GOTO1270

1270 RETURN

3000 '

3001 ' playscreen

3002 '

3010 COLOR14,1,14:WIDTH32:CLS:FORI=0TO20STEP2:LOCATE0,I:PRINTSTRING$(24,CHR$(201));:PRINTCHR$(215):LOCATE0,I+1:PRINTSTRING$(24,CHR$(200));:PRINTCHR$(215):NEXT:PRINTSTRING$(25,CHR$(200)):PRINTSTRING$(25,CHR$(200));

3011 A=1:FORI=0TO9:LOCATE1,A

3012 IFPF=1THENPRINT"CAR";T1(I)

3013 IFPF=2THENPRINT"CAR";T2(I)

3014 IFPF=3THENPRINT"CAR";T3(I)

3015 A=A+2:NEXT

3020 RETURN

3100 '

3101 ' moving sprites

3102 '

3110 FORH=0TO19STEP2

3115 DC=INT(RND(1)*6)+1

3120 LOCATE27,2:PRINT"DICE":LOCATE27,3:PRINTDC:LOCATE26,5:PRINT"MT PTS":LOCATE27,6:IFPF=1THENPRINTM1(H/2):DC=DC+M1(H/2)

3121 IFPF=2THENPRINTM2(H/2):DC=DC+M2(H/2)

3122 IFPF=3THENPRINTM3(H/2):DC=DC+M3(H/2)

3123 LOCATE26,8:PRINT"DV PTS":LOCATE27,9:IFPF=1THENPRINTD1(H/2):DC=DC+D1(H/2)

3124 IFPF=2THENPRINTD2(H/2):DC=DC+D2(H/2)

3125 IFPF=3THENPRINTD3(H/2):DC=DC+D3(H/2)

3130 SX(H)=SX(H)+DC:SX(H+1)=SX(H+1)+DC:GOSUB10000

3140 NEXTH

3199 RETURN

3200 '

3201 ' race

3202 '

3209 CLS:PRINT"  NOW IT'S YOUR TURN TO RACE":PRINT:PRINT"  LOOK AT YOUR CAR!!!":FORI=1TO1500:NEXT

3210 GOSUB 3000

3215 C=2:FORI=0TO18STEP2:SX(I)=0:SX(I+1)=0:SY(I)=I*8+3:SY(I+1)=I*8+3:SC(I+1)=C:SC(I)=1:C=C+1:NEXTI

3220 GOSUB10000

3230 ED=0:FORI=0TO19STEP2:IFSX(I)>180THENED=1

3240 NEXTI:IFED=0THENGOSUB3100:GOTO3230

3245 FORI=0TO18STEP2:DI(I/2)=SX(I):NEXT

3250 FORI=0TO19:SX(I)=-32:NEXTI:GOSUB10000

3290 RETURN

5000 '

5001 ' menu

5002 '

5010 COLOR1,14,14:CLS:LOCATE11,1:PRINT"MAIN MENU":LOCATE2,3:PRINT"1) YOUR SITUATION":LOCATE2,5:PRINT"2) BUY MOTOR POINTS":LOCATE2,7:PRINT"3) BUY DRIVER POINTS":LOCATE2,9:PRINT"4) SELL POINTS":LOCATE2,11:PRINT"5) VIEW CLASSIFICATION F1":LOCATE2,13

5020 PRINT"6) VIEW CLASSIFICATION F2":LOCATE 2,15:PRINT"7) VIEW CLASSIFICATION F3":LOCATE 2,17:PRINT"8) PLAY NEXT RACE":LOCATE2,21:PRINT"MAKE YOUR CHOICE"

5030 A$=INKEY$:IFA$=""THENGOTO5030

5040 IFVAL(A$)<1ORVAL(A$)>8THENGOTO5030

5050 ONVAL(A$)GOSUB5100,5200,5300,5400,5500,5520,5540,5600

5060 GOTO 5000

5100 CLS:PRINT:PRINT"YOUR NUMBER :":PRINT:PRINT"MOTOR POINTS :":PRINT:PRINT"DRIVER POINTS :":PRINT:PRINT"POINTS :":PRINT:PRINT"MONEY :"

5110 IFPF=1THENLOCATE20,1:PRINTT1(PP):LOCATE20,3:PRINTM1(PP):LOCATE20,5:PRINTD1(PP):LOCATE20,7:PRINTP1(PP):LOCATE20,9:PRINTMN

5115 IFPF=2THENLOCATE20,1:PRINTT2(PP):LOCATE20,3:PRINTM2(PP):LOCATE20,5:PRINTD2(PP):LOCATE20,7:PRINTP2(PP):LOCATE20,9:PRINTMN

5120 IFPF=3THENLOCATE20,1:PRINTT3(PP):LOCATE20,3:PRINTM3(PP):LOCATE20,5:PRINTD3(PP):LOCATE20,7:PRINTP3(PP):LOCATE20,9:PRINTMN

5130 LOCATE0,14:PRINT"PRESS ANY KEY"

5140 A$=INKEY$:IFA$=""THEN5140

5150 RETURN

5200 IFMN<200THENCLS:PRINT:PRINT"YOU DON'T HAVE MONEY!!":FORI=1TO300:NEXT:RETURN

5210 A=0:CLS:PRINT:PRINT"YOU HAVE ";MN;" MONEY":PRINT:PRINT"EACH POINT COST 200":PRINT:PRINT"HOW MANY POINTS DO YOU WANT":PRINT"TO BUY ";:INPUT A

5220 MN=MN-(A*200):IFPF=1THENM1(PP)=M1(PP)+A

5230 IFPF=2THENM2(PP)=M2(PP)+A

5240 IFPF=3THENM3(PP)=M3(PP)+A

5250 RETURN

5300 IFMN<200THENCLS:PRINT:PRINT"YOU DON'T HAVE MONEY!!":FORI=1TO300:NEXT:RETURN

5310 A=0:CLS:PRINT:PRINT"YOU HAVE ";MN;" MONEY":PRINT:PRINT"EACH POINT COST 200":PRINT:PRINT"HOW MANY POINTS DO YOU WANT":PRINT"TO BUY ";:INPUT A

5320 MN=MN-(A*200):IFPF=1THEND1(PP)=D1(PP)+A

5330 IFPF=2THEND2(PP)=D2(PP)+A

5340 IFPF=3THEND3(PP)=D3(PP)+A

5350 RETURN

5400 ONPFGOTO5410,5430,5450

5410 CLS:PRINT:PRINT"YOU HAVE ";M1(PP);" MOTOR POINTS":PRINT"YOU HAVE ";D1(PP);" DRIVER POINTS":PRINT:PRINT"YOU WILL GET 100 MONEY EACH":PRINT:INPUT"SELL MOTOR OR DRIVER POINTS (M/D)";A$

5412 IFA$<>"D"ANDA$<>"d"ANDA$<>"M"ANDA$<>"m"THEN5410

5414 LOCATE0,10:INPUT"HOW MANY POINTS ";A:IFA$="D"ORA$="d"ANDD1(PP)<ATHEN5414

5416 IFA$="M"ORA$="m"ANDM1(PP)<ATHEN5414

5418 IFA$="D"ORA$="d"THEND1(PP)=D1(PP)-A:MN=MN+(A*100)

5420 IFA$="M"ORA$="M"THENM1(PP)=M1(PP)-A:MN=MN+(A*100)

5422 RETURN

5430 CLS:PRINT:PRINT"YOU HAVE ";M2(PP);" MOTOR POINTS":PRINT"YOU HAVE ";D2(PP);" DRIVER POINTS":PRINT:PRINT"YOU WILL GET 100 MONEY EACH":PRINT:INPUT"SELL MOTOR OR DRIVER POINTS (M/D)";A$

5432 IFA$<>"D"ANDA$<>"d"ANDA$<>"M"ANDA$<>"m"THEN5430

5434 LOCATE0,10:INPUT"HOW MANY POINTS ";A:IFA$="D"ORA$="d"ANDD2(PP)<ATHEN5434

5436 IFA$="M"ORA$="m"ANDM2(PP)<ATHEN5434

5438 IFA$="D"ORA$="d"THEND2(PP)=D2(PP)-A:MN=MN+(A*100)

5440 IFA$="M"ORA$="M"THENM2(PP)=M2(PP)-A:MN=MN+(A*100)

5442 RETURN

5450 CLS:PRINT:PRINT"YOU HAVE ";M3(PP);" MOTOR POINTS":PRINT"YOU HAVE ";D3(PP);" DRIVER POINTS":PRINT:PRINT"YOU WILL GET 100 MONEY EACH":PRINT:INPUT"SELL MOTOR OR DRIVER POINTS (M/D)";A$

5452 IFA$<>"D"ANDA$<>"d"ANDA$<>"M"ANDA$<>"m"THEN5450

5454 LOCATE0,10:INPUT"HOW MANY POINTS ";A:IFA$="D"ORA$="d"ANDD3(PP)<ATHEN5454

5456 IFA$="M"ORA$="m"ANDM3(PP)<ATHEN5454

5458 IFA$="D"ORA$="d"THEND3(PP)=D3(PP)-A:MN=MN+(A*100)

5460 IFA$="M"ORA$="m"THENM3(PP)=M3(PP)-A:MN=MN+(A*100)

5462 RETURN

5500 RM=RN:IFRM=0ANDES=1THENRM=10

5505 CLS:PRINT"CLASSIFICATION AFTER ";RM;" RND":PRINT:PRINT"    CAR  PTS  MOT PTS DRV PTS"

5510 FORI=0TO9:PRINTUSING"##";I+1;:PRINT")  ";:PRINTUSING"##";T1(I);:PRINT"   ";:PRINTUSING"##";P1(I);:PRINT"    ";:PRINTUSING"##";M1(I);:PRINT"      ";:PRINTUSING"##";D1(I):NEXT:GOTO5580

5520 RM=RN:IFRM=0ANDES=1THENRM=10

5525 CLS:PRINT"CLASSIFICATION AFTER ";RM;" RND":PRINT:PRINT"    CAR  PTS  MOT PTS DRV PTS"

5530 FORI=0TO9:PRINTUSING"##";I+1;:PRINT")  ";:PRINTUSING"##";T2(I);:PRINT"   ";:PRINTUSING"##";P2(I);:PRINT"    ";:PRINTUSING"##";M2(I);:PRINT"      ";:PRINTUSING"##";D2(I):NEXT:GOTO5580

5540 RM=RN:IFRM=0ANDES=1THENRM=10

5545 CLS:PRINT"CLASSIFICATION AFTER ";RM;" RND":PRINT:PRINT"    CAR  PTS  MOT PTS DRV PTS"

5550 FORI=0TO9:PRINTUSING"##";I+1;:PRINT")  ";:PRINTUSING"##";T3(I);:PRINT"   ";:PRINTUSING"##";P3(I);:PRINT"    ";:PRINTUSING"##";M3(I);:PRINT"      ";:PRINTUSING"##";D3(I):NEXT:GOTO5580

5580 PRINT:PRINT"press any key"

5581 A$=INKEY$:IFA$=""THEN5581

5590 RETURN

5600 '

5601 ' next race

5602 '

5603 'formula1

5604 IFES=1THENES=0:GOSUB8000:RETURN

5605 GOSUB10100:IFMC=1THENGOTO5000

5610 IFPF=1THENGOSUB3200:GOTO5660

5620 CLS:PRINT"CALCULATING FORMULA 1 RACE":FORI=0TO9:DI(I)=0:NEXT

5630 FORI=0TO9:DC=INT(RND(1)*6)+1:DI(I)=DI(I)+(M1(I)*Z1(RN))+(D1(I)*Z2(RN))+DC:NEXT

5640 ED=0:FORI=0TO9:IFDI(I)>150THENED=1

5650 NEXT:IFED=0THEN5630

5660 FORI=0TO8:FORY=I+1TO9

5670 IFDI(Y)>DI(I)THENSWAPDI(Y),DI(I):SWAPT1(Y),T1(I):SWAPM1(Y),M1(I):SWAPD1(Y),D1(I):SWAPP1(Y),P1(I)

5672 NEXT:NEXT

5674 FORI=0TO9:IFT1(I)=CNTHENPP=I

5676 NEXT

5678 IFPF=1ANDPP=0THENMN=MN+200

5679 IFPF=1ANDPP=1THENMN=MN+180

5680 IFPF=1ANDPP=2THENMN=MN+160

5681 IFPF=1ANDPP=3THENMN=MN+140

5682 IFPF=1ANDPP=4THENMN=MN+120

5683 IFPF=1ANDPP=5THENMN=MN+100

5684 IFPF=1ANDPP=6THENMN=MN+80

5685 IFPF=1ANDPP=7THENMN=MN+60

5686 IFPF=1ANDPP=8THENMN=MN+40

5687 IFPF=1ANDPP=9THENMN=MN+20

5690 COLOR1,14,14:CLS:PRINT" FORMULA 1 RACE RESULTS":PRINT:PRINT"    CAR   DIS   PTS"

5700 FORI=0TO9:PRINTUSING"##";I+1;:PRINT")  ";:PRINTUSING"##";T1(I);:PRINT"   ";:PRINTUSING"###";DI(I);:PRINT"    ";:PRINTUSING"##";RP(I):NEXT

5705 LOCATE26,2:PRINT"MN";:LOCATE26,3:PRINT"200";:LOCATE26,4:PRINT"180";:LOCATE26,5:PRINT"160";:LOCATE26,6:PRINT"140";

5706 LOCATE26,7:PRINT"120";:LOCATE26,8:PRINT"100";:LOCATE26,9:PRINT" 80";:LOCATE26,10:PRINT" 60";:LOCATE26,11:PRINT" 40";:LOCATE26,12:PRINT" 20"

5710 PRINT:PRINT:PRINT"PRESS ANY KEY"

5711 A$=INKEY$:IFA$=""THEN5711

5720 FORI=0TO9:P1(I)=P1(I)+RP(I):NEXT

5730 FORI=0TO8:FORY=I+1TO9

5740 IFP1(Y)>P1(I)THENSWAPT1(Y),T1(I):SWAPM1(Y),M1(I):SWAPD1(Y),D1(I):SWAPP1(Y),P1(I)

5750 NEXT:NEXT

5760 FORI=0TO9:IFT1(I)=CNTHENPP=I

5770 NEXT

6000 ' formula2

6010 IFPF=2THENGOSUB3200:GOTO6060

6020 CLS:PRINT"CALCULATING FORMULA 2 RACE":FORI=0TO9:DI(I)=0:NEXT

6030 FORI=0TO9:DC=INT(RND(1)*6)+1:DI(I)=DI(I)+(M2(I)*Z1(RN))+(D2(I)*Z2(RN))+DC:NEXT

6040 ED=0:FORI=0TO9:IFDI(I)>150THENED=1

6050 NEXT:IFED=0THEN6030

6060 FORI=0TO8:FORY=I+1TO9

6070 IFDI(Y)>DI(I)THENSWAPDI(Y),DI(I):SWAPT2(Y),T2(I):SWAPM2(Y),M2(I):SWAPD2(Y),D2(I):SWAPP2(Y),P2(I)

6072 NEXT:NEXT

6074 FORI=0TO9:IFT2(I)=CNTHENPP=I

6076 NEXT

6078 IFPF=2ANDPP=0THENMN=MN+200

6079 IFPF=2ANDPP=1THENMN=MN+180

6080 IFPF=2ANDPP=2THENMN=MN+160

6081 IFPF=2ANDPP=3THENMN=MN+140

6082 IFPF=2ANDPP=4THENMN=MN+120

6083 IFPF=2ANDPP=5THENMN=MN+100

6084 IFPF=2ANDPP=6THENMN=MN+80

6085 IFPF=2ANDPP=7THENMN=MN+60

6086 IFPF=2ANDPP=8THENMN=MN+40

6087 IFPF=2ANDPP=9THENMN=MN+20

6090 COLOR1,14,14:CLS:PRINT" FORMULA 2 RACE RESULTS":PRINT:PRINT"    CAR   DIS   PTS"

6100 FORI=0TO9:PRINTUSING"##";I+1;:PRINT")  ";:PRINTUSING"##";T2(I);:PRINT"   ";:PRINTUSING"###";DI(I);:PRINT"    ";:PRINTUSING"##";RP(I):NEXT

6105 LOCATE26,2:PRINT"MN";:LOCATE26,3:PRINT"200";:LOCATE26,4:PRINT"180";:LOCATE26,5:PRINT"160";:LOCATE26,6:PRINT"140";

6106 LOCATE26,7:PRINT"120";:LOCATE26,8:PRINT"100";:LOCATE26,9:PRINT" 80";:LOCATE26,10:PRINT" 60";:LOCATE26,11:PRINT" 40";:LOCATE26,12:PRINT" 20"

6110 PRINT:PRINT:PRINT"PRESS ANY KEY"

6111 A$=INKEY$:IFA$=""THEN6111

6120 FORI=0TO9:P2(I)=P2(I)+RP(I):NEXT

6130 FORI=0TO8:FORY=I+1TO9

6140 IFP2(Y)>P2(I)THENSWAPT2(Y),T2(I):SWAPM2(Y),M2(I):SWAPD2(Y),D2(I):SWAPP2(Y),P2(I)

6150 NEXT:NEXT

6160 FORI=0TO9:IFT2(I)=CNTHENPP=I

6170 NEXT

6500 ' formula3

6510 IFPF=3THENGOSUB3200:GOTO6560

6520 CLS:PRINT"CALCULATING FORMULA 3 RACE":FORI=0TO9:DI(I)=0:NEXT

6530 FORI=0TO9:DC=INT(RND(1)*6)+1:DI(I)=DI(I)+(M3(I)*Z1(RN))+(D3(I)*Z2(RN))+DC:NEXT

6540 ED=0:FORI=0TO9:IFDI(I)>150THENED=1

6550 NEXT:IFED=0THEN6530

6560 FORI=0TO8:FORY=I+1TO9

6570 IFDI(Y)>DI(I)THENSWAPDI(Y),DI(I):SWAPT3(Y),T3(I):SWAPM3(Y),M3(I):SWAPD3(Y),D3(I):SWAPP3(Y),P3(I)

6572 NEXT:NEXT

6574 FORI=0TO9:IFT3(I)=CNTHENPP=I

6576 NEXT

6578 IFPF=3ANDPP=0THENMN=MN+200

6579 IFPF=3ANDPP=1THENMN=MN+180

6580 IFPF=3ANDPP=2THENMN=MN+160

6581 IFPF=3ANDPP=3THENMN=MN+140

6582 IFPF=3ANDPP=4THENMN=MN+120

6583 IFPF=3ANDPP=5THENMN=MN+100

6584 IFPF=3ANDPP=6THENMN=MN+80

6585 IFPF=3ANDPP=7THENMN=MN+60

6586 IFPF=3ANDPP=8THENMN=MN+40

6587 IFPF=3ANDPP=9THENMN=MN+20

6590 COLOR1,14,14:CLS:PRINT" FORMULA 3 RACE RESULTS":PRINT:PRINT"    CAR   DIS   PTS"

6600 FORI=0TO9:PRINTUSING"##";I+1;:PRINT")  ";:PRINTUSING"##";T3(I);:PRINT"   ";:PRINTUSING"###";DI(I);:PRINT"    ";:PRINTUSING"##";RP(I):NEXT

6605 LOCATE26,2:PRINT"MN";:LOCATE26,3:PRINT"200";:LOCATE26,4:PRINT"180";:LOCATE26,5:PRINT"160";:LOCATE26,6:PRINT"140";

6606 LOCATE26,7:PRINT"120";:LOCATE26,8:PRINT"100";:LOCATE26,9:PRINT" 80";:LOCATE26,10:PRINT" 60";:LOCATE26,11:PRINT" 40";:LOCATE26,12:PRINT" 20"

6610 PRINT:PRINT:PRINT"PRESS ANY KEY"

6611 A$=INKEY$:IFA$=""THEN6611

6620 FORI=0TO9:P3(I)=P3(I)+RP(I):NEXT

6630 FORI=0TO8:FORY=I+1TO9

6640 IFP3(Y)>P3(I)THENSWAPT3(Y),T3(I):SWAPM3(Y),M3(I):SWAPD3(Y),D3(I):SWAPP3(Y),P3(I)

6650 NEXT:NEXT

6660 FORI=0TO9:IFT3(I)=CNTHENPP=I

6670 NEXT

7000 ' end races

7010 GOSUB7100:RN=RN+1:IFRN=10THENRN=0:ES=1

7020 RETURN

7100 '

7101 ' casualities

7102 '

7103 ' FORMULA1

7110 COLOR 1,8:CLS

7115 PRINT"   CASUALITIES FORMULA 1":PRINT

7120 FORI=0TO9:PRINT"CAR ";T1(I):GOSUB7700

7130 IFV=2THENM1(I)=M1(I)-1

7140 IFV=4THENM1(I)=M1(I)+1

7150 IFV=6THEND1(I)=D1(I)+1

7160 IFV=8THEND1(I)=D1(I)-1

7170 IFV=10THENM1(I)=M1(I)-2

7180 IFV=13THENM1(I)=M1(I)+2

7190 IFV=21THEND1(I)=D1(I)+2

7200 IFV=23THEND1(I)=D1(I)-2

7210 IFV=16 AND T1(I)=CN THEN MN=MN-50

7220 IFV=17 AND T1(I)=CN THEN MN=MN+100

7230 IFV=18 AND T1(I)=CN THEN MN=MN-100

7240 IFV=19 AND T1(I)=CN THEN MN=MN+200

7250 IFM1(I)<0THENM1(I)=0

7260 IFD1(I)<0THEND1(I)=0

7270 IFMN<0THENMN=0

7280 NEXT

7290 PRINT"PRESS ANY KEY";

7300 A$=INKEY$:IFA$=""THEN7300

7305 ' FORMULA2

7310 CLS

7315 PRINT"   CASUALITIES FORMULA 2":PRINT

7320 FORI=0TO9:PRINT"CAR ";T2(I):GOSUB7700

7330 IFV=2THENM2(I)=M2(I)-1

7340 IFV=4THENM2(I)=M2(I)+1

7350 IFV=6THEND2(I)=D2(I)+1

7360 IFV=8THEND2(I)=D2(I)-1

7370 IFV=10THENM2(I)=M2(I)-2

7380 IFV=13THENM2(I)=M2(I)+2

7390 IFV=21THEND2(I)=D2(I)+2

7400 IFV=23THEND2(I)=D2(I)-2

7410 IFV=16 AND T2(I)=CN THEN MN=MN-50

7420 IFV=17 AND T2(I)=CN THEN MN=MN+100

7430 IFV=18 AND T2(I)=CN THEN MN=MN-100

7440 IFV=19 AND T2(I)=CN THEN MN=MN+200

7450 IFM2(I)<0THENM2(I)=0

7460 IFD2(I)<0THEND2(I)=0

7470 IFMN<0THENMN=0

7480 NEXT

7490 PRINT"PRESS ANY KEY";

7500 A$=INKEY$:IFA$=""THEN7500

7505 'FORMULA 3

7510 CLS

7515 PRINT"   CASUALITIES FORMULA 3":PRINT

7520 FORI=0TO9:PRINT"CAR ";T3(I):GOSUB7700

7530 IFV=2THENM3(I)=M3(I)-1

7540 IFV=4THENM3(I)=M3(I)+1

7550 IFV=6THEND3(I)=D3(I)+1

7560 IFV=8THEND3(I)=D3(I)-1

7570 IFV=10THENM3(I)=M3(I)-2

7580 IFV=13THENM3(I)=M3(I)+2

7590 IFV=21THEND3(I)=D3(I)+2

7600 IFV=23THEND3(I)=D3(I)-2

7610 IFV=16 AND T3(I)=CN THEN MN=MN-50

7620 IFV=17 AND T3(I)=CN THEN MN=MN+100

7630 IFV=18 AND T3(I)=CN THEN MN=MN-100

7640 IFV=19 AND T3(I)=CN THEN MN=MN+200

7650 IFM3(I)<0THENM3(I)=0

7660 IFD3(I)<0THEND3(I)=0

7670 IFMN<0THENMN=0

7680 NEXT

7690 PRINT"PRESS ANY KEY";

7695 A$=INKEY$:IFA$=""THEN7695

7699 COLOR1,14:RETURN

7700 V=INT(RND(-TIME)*24)+1

7750 IFV=1THENPRINT"Nothing new by now":GOTO7990

7760 IFV=2THENPRINT"Problems in motor. -1 point":GOTO7990

7770 IFV=3THENPRINT"Nothing new by now":GOTO7990

7780 IFV=4THENPRINT"Solve a motor problem. +1 point":GOTO7990

7790 IFV=5THENPRINT"Nothing new":GOTO7990

7800 IFV=6THENPRINT"Your driver train good. +1 pt":GOTO7990

7810 IFV=7THENPRINT"Nothing new by now":GOTO7990

7820 IFV=8THENPRINT"Your driver feels bad. -1 point":GOTO7990

7830 IFV=9THENPRINT"Nothing new":GOTO7990

7840 IFV=10THENPRINT"Severe problems to motor.-2 pts":GOTO7990

7850 IFV=11THENPRINT"All is OK":GOTO7990

7860 IFV=12THENPRINT"Everithing's fine":GOTO7990

7870 IFV=13THENPRINT"Improve the motor. +2 points":GOTO7990

7880 IFV=14THENPRINT"all work is regular":GOTO7990

7890 IFV=15THENPRINT"Nothing new":GOTO7990

7900 IFV=16THENPRINT"Buy spare parts: -50 MN":GOTO7990

7910 IFV=17THENPRINT"New sponsor: +100 MN":GOTO7990

7920 IFV=18THENPRINT"Pay a fine: -100 MN":GOTO7990

7930 IFV=19THENPRINT"New sponsor: +200 MN":GOTO7990

7940 IFV=20THENPRINT"All is OK":GOTO7990

7950 IFV=21THENPRINT"Your driver train good. +2 pts":GOTO7990

7960 IFV=22THENPRINT"No news":GOTO7990

7970 IFV=23THENPRINT"Your driver crashed. -2 pts":GOTO7990

7980 IFV=24THENPRINT"Nothing new":GOTO7990

7990 RETURN

8000 '

8001 ' new season

8002 '

8010 CLS:PRINT"   END SEASON RESULTS":LOCATE0,3:PRINT"FORMULA 1":LOCATE11,3:PRINT"FORMULA 2":LOCATE21,3:PRINT"FORMULA 3"

8020 LOCATE0,5:PRINT"CAR  PTS":LOCATE11,5:PRINT"CAR  PTS":LOCATE21,5:PRINT"CAR  PTS"

8030 FORI=0TO9:LOCATE0,7+I:PRINTUSING"##";T1(I);:PRINT"  ";:PRINTUSING"##";P1(I):NEXT

8040 FORI=0TO9:LOCATE11,7+I:PRINTUSING"##";T2(I);:PRINT"  ";:PRINTUSING"##";P2(I):NEXT

8050 FORI=0TO9:LOCATE21,7+I:PRINTUSING"##";T3(I);:PRINT"  ";:PRINTUSING"##";P3(I):NEXT

8060 FORI=0TO9:P1(I)=0:P2(I)=0:P3(I)=0:NEXT:SWAPT1(8),T2(0):SWAPT1(9),T2(1):SWAPM1(8),M2(0):SWAPM1(9),M2(1):SWAPD1(8),D2(0):SWAPD1(9),D2(1):SWAPT2(8),T3(0):SWAPT2(9),T3(1):SWAPM2(8),M3(0):SWAPM2(9),M3(1):SWAPD2(8),D3(0):SWAPD2(9),D3(1)

8070 FORI=0TO9:IFT1(I)=CNTHENPF=1:PP=I

8080 NEXT:FORI=0TO9:IFT2(I)=CNTHENPF=2:PP=I

8090 NEXT:FORI=0TO9:IFT3(I)=CNTHENPF=3:PP=I

8100 NEXT:LOCATE2,20:PRINT"PRESS ANY KEY"

8110 A$=INKEY$:IFA$=""THEN8110

8120 IFT1(0)=CNTHEN8500

8490 RETURN

8500 '

8501 ' END OF THE GAME

8502 '

8510 SCREEN2:COLOR1,14,14:CLS

8520 A1=0:B1=0:A2=255:B2=191:C=11

8530 FORI=1TO5

8540 LINE(A1,B1)-(A2,B2),C,BF

8550 A1=A1+10:B1=B1+10:A2=A2-10:B2=B2-10:C=C+1

8560 NEXT:C=15

8570 PRESET(50,55),C

8580 OPEN"GRP:"FOROUTPUTAS#1

8590 COLOR1:PRINT#1,"CONGRATULATIONS!"

8600 PRESET(50,65),C:COLOR1:PRINT#1,"YOU ARE THE CHAMPION"

8610 PRESET(50,75),C:COLOR1:PRINT#1,"OF FORMULA 1 !!"

8620 PRESET(50,105),C:COLOR1:PRINT#1,"PRESS A KEY TO END"

8630 A$=INKEY$:IFA$=""THEN8630

8640 END

10000 REM putsprites

10010 FORI=0TO19STEP2:PUTSPRITEI,(SX(I),SY(I)),SC(I),0:PUTSPRITEI+1,(SX(I+1),SY(I+1)),SC(I+1),1:NEXTI

10020 RETURN

10100 MC=0:IFRN=0THENGOTO10110ELSEGOTO10200

10110 IFPF=1THENA=300ELSEIFPF=2THENA=200ELSEIFPF=3THENA=100

10120 CLS:PRINT"  START OF THE SEASON":PRINT:PRINT"YOU HAVE TO PAY ";A:PRINT:PRINT"YOUR MONEY IS ";MN:PRINT:IFMN<ATHENPRINT"YOU HAVE NOT ENOUGH MONEY":PRINT"GO TO SELL POINTS!!":MC=1:RETURN

10130 MN=MN-A:PRINT"YOUR MONEY IS NOW ";MN:PRINT:PRINT"PRESS ANY KEY"

10140 A$=INKEY$:IFA$=""THEN10140

10200 CLS:PRINT"    RACE NUMBER ";RN+1:PRINT:PRINT"CIRCUIT  ";RC$(RN):PRINT:PRINT"MOTOR POINTS VALUE  ";Z1(RN):PRINT:PRINT"DRIVER POINTS VALUE  ";Z2(RN)

10210 PRINT:PRINT:PRINT"PRESS ANY KEY"

10220 A$=INKEY$:IFA$=""THEN10220

10230 RETURN

50000 '

50010 ' car sprite

50020 '

50030 DATA &H00,&H00,&H38,&H18,&H18,&H00,&H00,&H00

50040 DATA &H00,&H00,&H00,&H18,&H18,&H38,&H00,&H00

50050 DATA &H00,&H00,&H00,&H1C,&H1C,&H00,&H00,&HF0

50060 DATA &HF0,&H00,&H00,&H1C,&H1C,&H00,&H00,&H00

50070 ' color 15

50080 DATA &H00,&H00,&H00,&HE1,&HE7,&HFF,&HFF,&HFF

50090 DATA &HFF,&HFF,&HFF,&HE7,&HE1,&H00,&H00,&H00

50100 DATA &H00,&H00,&H00,&H80,&HE3,&HFF,&HFF,&H0F

50110 DATA &H0F,&HFF,&HFF,&HE3,&H80,&H00,&H00,&H00,*

50130 RESTORE 50030

50180 S=BASE(9)

50190 READ R$: IF R$="*" THEN RETURN ELSE VPOKE S,VAL(R$):S=S+1:GOTO 50190

