100 'HELLO KitTY

110 KEY6,"screen0"+CHR$(13)

120 SCREEN 1,,0

130 PLAY"v15","v15","v15"

140 WIDTH 32

150 DEFINTA-Z

160 COLOR15,0,0

170 POKE &HFBB1,1:'<=- set to 1 before release!!!!

180 KEYOFF

190 GOSUB 250:'screen init

200 GOSUB 640:'start screen

210 GOSUB 1360:'build field

220 GOSUB 1100

230 GOSUB 1660:'exit to basic

240 'fonts and colors

250 VPOKE 784,&B01111110

260 VPOKE 785,&B10000001

270 VPOKE 786,&B10100101

280 VPOKE 787,&B10000001

290 VPOKE 788,&B10100001

300 VPOKE 789,&B10011101

310 VPOKE 790,&B10000001

320 VPOKE 791,&B01111110

330 'c

340 VPOKE 792,&B00000000

350 VPOKE 793,&B00111110

360 VPOKE 794,&B01001111

370 VPOKE 795,&B01001111

380 VPOKE 796,&B01111111

390 VPOKE 797,&B01111111

400 VPOKE 798,&B01111111

410 VPOKE 799,&B00111110

420 'h

430 VPOKE 832,&B00000000

440 VPOKE 833,&B11111011

450 VPOKE 834,&B11111011

460 VPOKE 835,&B11111011

470 VPOKE 836,&B00000000

480 VPOKE 837,&B10111111

490 VPOKE 838,&B10111111

500 VPOKE 839,&B10111111

510 'x

520 VPOKE 960,&B00100100

530 VPOKE 961,&B11011011

540 VPOKE 962,&B01100110

550 VPOKE 963,&B00111100

560 VPOKE 964,&B10111101

570 VPOKE 965,&B11011011

580 VPOKE 966,&B01100110

590 VPOKE 967,&B00111100

600 VPOKE 8204,&H30

610 VPOKE 8205,&H6E

620 VPOKE 8207,&HA0

630 RETURN

640 'intro screen

650 L=5

660 S=0

670 W=0

680 G=1

690 PRINT "    hhhhhhhhhhhhhhhhhhhhhhh

700 PRINT "    hxxxxxxxxxxxxxxxxxxxxxh

710 PRINT "    hxhhh h h h h  h hhh xh

720 PRINT "    hxh h h h h hh h h  hxh

730 PRINT "    hxhhh h h h h hh h  hxh

740 PRINT "    hxh   h h h h  h h  hxh

750 PRINT "    hxh    h h  h  h hhh xh

760 PRINT "    hxxxxxxxxxxxxxxxxxxxxxh

770 PRINT "    h                     h

780 PRINT "    h OF JE WORST LUST    h

790 PRINT "    h     SPECIAL EDITION h

800 PRINT "    h                     h

810 PRINT "    hx(C) 2009 METAL SOFTxh

820 PRINT "    hhhhhhhhhhhhhhhhhhhhhhh

830 PRINT "

840 PRINT "

850 PRINT "     [PUSH SPACE TO START]"

860 PRINT:PRINT:PRINT:PRINT:PRINT

870 PRINT " x MADE IN 1 DAY FOR MSXDEV08 x"

880 PLAY"l64o1cdcecfcg","l64o4s11m10cdcecfcg"

890 D=STICK(0)ORSTICK(1)

900 'A$=INKEY$

910 IFA$="1"THENS=2

920 IFA$="3"THENS=2

930 IFA$="4"THENS=3

940 IFA$="5"THENS=4

950 IFA$="6"THENS=5

960 IFA$="7"THENS=6

970 IFA$="8"THENS=7

980 '

990 IF D=3 THEN G=G+1

1000 IF D=7 THEN G=G-1

1010 IF G<0 THEN G=0

1020 IF G>3 THEN G=3

1030 IF G=0 THEN LOCATE 12,18:PRINT "< SLOW >":T=25:FORI=0TO100:NEXT

1040 IF G=1 THEN LOCATE 12,18:PRINT "<NORMAL>":T=10:FORI=0TO100:NEXT

1050 IF G=2 THEN LOCATE 12,18:PRINT "< FAST >":T=5 :FORI=0TO100:NEXT

1060 IF G=3 THEN LOCATE 12,18:PRINT "<INSANE>":T=1 :FORI=0TO100:NEXT

1070 IF STRIG(0)+STRIG(1)+STRIG(2)+STRIG(3)<0 THEN 1080 ELSE 890

1080 CLS

1090 RETURN

1100 E=D

1110 FORI=0TOT

1120 M=STICK(0)ORSTICK(1):IF (M=1 OR M=3 OR M=5 OR M=7) THEN D=M

1130 NEXT

1140 IFE=0 THEN 1100

1150 VPOKE (&H1800+X+Y*32),99

1160 IF D=0 THEN D=E:VPOKE (&H1800+X+Y*32),99

1170 'prevent player from reversing into "itself"

1180 IF D=1 AND E=5 THEN D=5

1190 IF D=5 AND E=1 THEN D=1

1200 IF D=3 AND E=7 THEN D=7

1210 IF D=7 AND E=3 THEN D=3

1220 'stick controls

1230 IFD=1 THEN Y=Y-1

1240 IFD=3 THEN X=X+1

1250 IFD=5 THEN Y=Y+1

1260 IFD=7 THEN X=X-1

1270 IF VPEEK(&H1800+X+Y*32)=120 THEN F=F+1:PLAY"l64o4co6c":W=W+100:GOTO1290

1280 IF VPEEK(&H1800+X+Y*32)>32 AND D>0 THEN GOSUB 1670

1290 VPOKE &H1800+X+Y*32,98

1300 W=W+1

1310 IF C=F THEN GOTO 1790

1320 A$=INKEY$

1330 'IF A$=CHR$(27)THEN 1620

1340 LOCATE 0,0:PRINT USING "SCORE:######";W

1350 GOTO 1100

1360 'BUILD SCREEN

1370 E=0:D=0:'reset stick

1380 LOCATE 0,0:PRINT USING "SCORE:######";W

1390 LOCATE 13,0:PRINT USING "STAGE:##";S+1

1400 IFL>0 THEN FORI=0TOL-1:VPOKE&H1800+25+I,98:NEXT

1410 FORX=0TO31:VPOKE(&H1800+X+1*32),104:VPOKE(&H1800+X+23*32),104:NEXT

1420 FORY=1TO23:VPOKE(&H1800+0+Y*32),104:VPOKE(&H1800+31+Y*32),104:NEXT

1430 IF L<0 THEN GOTO 1740

1440 'X=8:Y=8:VPOKE(&H1800+X+Y*32),98

1450 LOCATE 10,12:PRINT"[GET READY]"

1460 F=0:'set collected flowers to 0

1470 FORI=0TO1000:NEXT

1480 LOCATE 10,12:PRINT"           "

1490 IFS=0 THEN RESTORE 1920

1500 IFS=1 THEN RESTORE 2150

1510 IFS=2 THEN RESTORE 2380

1520 IFS=3 THEN RESTORE 2610

1530 IFS=4 THEN RESTORE 2840

1540 IFS=5 THEN RESTORE 3070

1550 IFS=6 THEN RESTORE 3300

1560 IFS=7 THEN RESTORE 3530

1570 FORI=0TO20:LOCATE1,I+2:READ A$:PRINT A$

1580 Q=INSTR(A$,"b"):IFQ>0THEN X=Q:Y=I+2

1590 NEXT

1600 READ C

1610 RETURN

1620 SCREEN 0:WIDTH32:POKE &HFBB1,0

1630 'IF A$=CHR$(27)THEN 1660

1640 FORI=0TO100:NEXT

1650 GOTO 1250

1660 'SCREEN 0:WIDTH80:POKE &HFBB1,0:END:'Kill and return to basic! :)

1670 PLAY"l16v15o2bge"

1680 VPOKE 8204,&H30:VPOKE 8205,&H60

1690 FORI=0TO7:VPOKE784+I,0:VPOKE792+I,0:VPOKE832+I,0:FORP=0TO100:NEXT:NEXT:FORI=0TO1000:NEXT

1700 CLS

1710 GOSUB 240

1720 L=L-1

1730 GOTO 210

1740 LOCATE10,12:PRINT"GAME OVER"

1750 PLAY"l64o4co3co2c","l64o3go2go1g"

1760 FORI=0 TO 3000:NEXT

1770 FORI=0TO24:LOCATE0,24:PRINT CHR$(13):NEXT

1780 GOTO 190

1790 IF S<>7 THEN LOCATE7,10:PRINT"[STAGE COMPLETE!]"

1800 LOCATE 0,0:PRINT USING "SCORE:######";W

1810 VPOKE 8204,&H30:VPOKE 8205,&H60

1820 FORI=0TO7:VPOKE784+I,0:VPOKE792+I,0:VPOKE832+I,0:FORP=0TO100:NEXT:NEXT:FORI=0TO1000:NEXT

1830 PLAY"v15l64o1ao2ao3ao4ao5ao6ao7ao8a"

1840 FORI=0TO2000:NEXT

1850 FORI=0TO7:VPOKE792+I,0:VPOKE784+I,0:VPOKE832+I,0:FORP=0TO100:NEXT:NEXT:FORI=0TO1000:NEXT

1860 S=S+1

1870 IF S>7 THEN 3810

1880 CLS

1890 GOSUB 240

1900 GOSUB 1360

1910 GOSUB 1100

1920 'Stage 1

1930 DATA "hhhhhhh                      h"

1940 DATA "hhhhhhh                      h"

1950 DATA "hhhhhhh                      h"

1960 DATA "hhhhhhh                      h"

1970 DATA "hhhhhhh                b     h"

1980 DATA "hhhhhhh  x                   h"

1990 DATA "hhhhhhh                      h"

2000 DATA "hhhhhhhhhhhh         x       h"

2010 DATA "hhhhhhhhhhhhh                h"

2020 DATA "h COLLECT hhhhhhhhh   hhhhhhhhh"

2030 DATA "hh  THE  hhh                 h"

2040 DATA "h FLOWERS h   x              h"

2050 DATA "hhhhhhhhhh   x               h"

2060 DATA "hhhhhhhhh                    h"

2070 DATA "hhhhhhhh     hhhhhhhhhhhhh   h"

2080 DATA "hhhhhhh     hh               h"

2090 DATA "hhhhhhhh   hh     x    x     h"

2100 DATA "hhhhhhhhh hh                 h"

2110 DATA "hhhhhhhhhhh     x   x        h"

2120 DATA "hhhhhhhhhhh                  h"

2130 DATA "hhhhhhhhhhhh                 h"

2140 DATA 8

2150 'Stage 2

2160 DATA "h b h       h        h       h"

2170 DATA "h   h       h  x x   h  x x  h"

2180 DATA "h   h   h   h  x x   h  x x  h"

2190 DATA "h   h   h   h                h"

2200 DATA "h   h   h   h  x             h"

2210 DATA "h   h x h   h                h"

2220 DATA "h   h x h   h  x             h"

2230 DATA "h   h   h x h                h"

2240 DATA "h   h   h x h  x        x    h"

2250 DATA "h   h   h   h                h"

2260 DATA "h   h   h   h                h"

2270 DATA "h   h   hx  h                h"

2280 DATA "h   h   hx  h           x    h"

2290 DATA "h   h   h   h                h"

2300 DATA "h   h   h   h   x            h"

2310 DATA "h   h   h   h                h"

2320 DATA "h x h   h   h              hhh"

2330 DATA "h x h   h               hhhhhh"

2340 DATA "h       h         hhhhhhhhhhhh"

2350 DATA "h       h   hhhhhhhhhhhhhhhhhh"

2360 DATA "hhhhhhhhhhhhhhhhhhhhhhhhhhhhhh"

2370 DATA 22

2380 'Stage 3

2390 DATA "h     hh                     h"

2400 DATA "h     hh                x    h"

2410 DATA "h     xx                     h"

2420 DATA "h     hh                     h"

2430 DATA "h      hh                   hh"

2440 DATA "h       hh                 hhh"

2450 DATA "hh  x    hh hhhh          hhhh"

2460 DATA "hhh        hhhhhh        hhhhh"

2470 DATA "hhhh      hh            hhhhhh"

2480 DATA "hhhhh    hh     x      hhhhhhh"

2490 DATA "hhhh     hh  b           hhhhh"

2500 DATA "hhh      hh     x      x  hhhh"

2510 DATA "hh     hh hh           x  hhhh"

2520 DATA "h x  hhh   hhhhhh        hhhhh"

2530 DATA "h   hh   x  hhhh       hhhhhhh"

2540 DATA "h xhh               x   hhhhhh"

2550 DATA "h  hh  x     x           hhhhh"

2560 DATA "h x hh                    hhhh"

2570 DATA "h    hh                    hhh"

2580 DATA "h x   hh    x               hh"

2590 DATA "h      hh                    h"

2600 DATA 17

2610 'Stage 4

2620 DATA "hhhhhhhhhhhhhhhhhhhhhhhhhhhhhh"

2630 DATA "h       b hh    x          x h"

2640 DATA "h xx      hh   hhh      hhhhhh"

2650 DATA "h      xx hh                 h"

2660 DATA "h xx      hh                 h"

2670 DATA "h      xx hh        x        h"

2680 DATA "h xx      hh                 h"

2690 DATA "h      xx hh                 h"

2700 DATA "h xx      hhhhhhhh  x hhhhhhhh"

2710 DATA "h      xx hh                 h"

2720 DATA "h xx      hh  x              h"

2730 DATA "h      xx hh             x   h"

2740 DATA "h xx      hh                 h"

2750 DATA "h      xx hhhhhhhh  x hhhhhhhh"

2760 DATA "h         hh                 h"

2770 DATA "h         hh                 h"

2780 DATA "h    x    hhhhhhhh           h"

2790 DATA "h    x           h  x  hhhhhhh"

2800 DATA "h         xx     h  x  hhhhhhh"

2810 DATA "h                            h"

2820 DATA "h         hh  x     x        h"

2830 DATA 39

2840 'Stage 5

2850 DATA "hhhhhhhhhhhhhhhhhhhhhhhhhhhhhh"

2860 DATA "hbhh    h                    h"

2870 DATA "h hh h  h                    h"

2880 DATA "h hh h  h    x       x       h"

2890 DATA "h hh h  h   x x     x x      h"

2900 DATA "h hh h  h                    h"

2910 DATA "h hh h  h       x x          h"

2920 DATA "h hh h  h       x x          h"

2930 DATA "h x  h  h                    h"

2940 DATA "hhhhhh  h        h           h"

2950 DATA "h x     h       hhh          h"

2960 DATA "h hhhhhhh      hhhhh         h"

2970 DATA "h hhhhhhh     hhhhhhh        h"

2980 DATA "hxhhhhhhh       hhh          h"

2990 DATA "h hhhhhhh       hhh          h"

3000 DATA "h               hhh          h"

3010 DATA "h   x    xxx  x              h"

3020 DATA "h   x    x x  x              h"

3030 DATA "h   x    x x  x              h"

3040 DATA "h   xxx  xxx  xxx            h"

3050 DATA "h                            h"

3060 DATA 35

3070 'Stage 6

3080 DATA "                             b"

3090 DATA " hhhhhhhhhhhhhhhhhhhhhhhhhhhh "

3100 DATA " hx                        xh "

3110 DATA " h hhhhhhhhhhhhhhhhhhhhhhh  h "

3120 DATA " h hx                   xh  h "

3130 DATA " h h hhhhhhhhhhhhhhhhhhh h  h "

3140 DATA " h h hx               xh h  h "

3150 DATA " h h h hhhhhhhhhhhhhhh h h  h "

3160 DATA " h h h hx           xh h h  h "

3170 DATA " h h h h hhhhhhhhhhh h h h  h "

3180 DATA " h h h h  xxxxxxxxxh h h h  h "

3190 DATA " h h h hhhhhhhhhhhhh h h h  h "

3200 DATA " h h hx             xh h h  h "

3210 DATA " h h hhhhhhhhhhhhhhhhh h h  h "

3220 DATA " h hx                 xh h  h "

3230 DATA " h hhhhhhhhhhhhhhhhhhhhh h  h "

3240 DATA " hx                     xh  h "

3250 DATA " hhhhhhhhhhhhhhhhhhhhhhhhh  h "

3260 DATA "x                          xh "

3270 DATA " hhhhhhhhhhhhhhhhhhhhhhhhhhhh "

3280 DATA "                              "

3290 DATA 25

3300 'Stage 7

3310 DATA "b h             h     hhhhhhhh"

3320 DATA "h h        hhhhhh h    hhhhhhh"

3330 DATA "h  h       h      h        xhh"

3340 DATA "h  h       hhhhh  hhhhhhhhh hh"

3350 DATA "xh  h      h      hhhhhhhhh hh"

3360 DATA " h  h      h hhhhhhhhhhhhhh hh"

3370 DATA " xh  h              h         "

3380 DATA "  h  h              hxhhhhhhhh"

3390 DATA "  xh  h             h         "

3400 DATA "   h  hhhhh         hhhhhhhhh "

3410 DATA "   h   xx hhhhh             h "

3420 DATA "   h   xx     h     hhhhhhhhh "

3430 DATA "   hhhhhhhhhh h     h         "

3440 DATA "   hhhhhhhhhhxh     h hhhhhhhh"

3450 DATA "   hhhhhhhhhh h     h         "

3460 DATA "   hhhhhhhhhh h     hhhhhhhhh "

3470 DATA "   hhhhhhhhhh  h            h "

3480 DATA "   hhhhhhhhhh  h            h "

3490 DATA "   h  x    xh               h "

3500 DATA "   x        hhhhhhhhhhhhhh hh "

3510 DATA "   h  x                       "

3520 DATA 14

3530 'Stage 8

3540 DATA "hbh THANKS FOR PLAYING PWND!  "

3550 DATA "h h                           "

3560 DATA "h h GREETINGS GO TO:          "

3570 DATA "h h  - THE OPENMSX TEAM       "

3580 DATA "h h  - THE BLUEMSX TEAM       "

3590 DATA "h h  - THE MRC USERS          "

3600 DATA "h h  - MSX POSSE              "

3610 DATA "h h  - ALL MSX(DEV) FANS      "

3620 DATA "h h                 AND YOU!  "

3630 DATA "h h                           "

3640 DATA "h h  SPECIAL THANKS TO:       "

3650 DATA "h h   - BIFI                  "

3660 DATA "h h   - HAP                   "

3670 DATA "h h  FOR HELPING ME WITH THE  "

3680 DATA "h h  SOMEWHAT TECHNICAL STUFF "

3690 DATA "h h                           "

3700 DATA "h h  KEEP MSXDEV ALIVE!       "

3710 DATA "h h    SEE YOU NEXT YEAR!!    "

3720 DATA "h h                           "

3730 DATA "h h                           "

3740 DATA "hxh                           "

3750 DATA 1

3760 'YOU SHOULD HAVE USED THE LISTING COMMAND

3770 'IN THE CONSOLE OF OPENMSX, IT WOULD HAVE BEEN

3780 'EASIER TO GET THE LISING ;)

3790 '

3800 ' THANKS AND GREETZ FROM VAMPIER

3810 FORI=0TO1000:NEXT:COLOR14

3820 FORI=0TO1000:NEXT:COLOR7

3830 FORI=0TO1000:NEXT:COLOR5

3840 FORI=0TO1000:NEXT:COLOR4

3850 FORI=0TO1000:NEXT:COLOR0

3860 CLS:COLOR15

3870 SCREEN 1:LOCATE 11,12:PRINT"[THE END]"

3880 PLAY"l64o1co2do3eo4eo5fo6go7ao8b","l16o1cdefgab","l16o3cdefgab"

3890 LOCATE 0,15:PRINT "   [PUSH SPACE TO CONTINUE]

3900 IF STRIG(0)+STRIG(1)+STRIG(2)+STRIG(3)<0 THEN RUN ELSE 3900

