10 REM'''''''''''''''''
20 REM                '
30 REM  NIGHT ESCAPE  '
40 REM                '
50 REM SHERIF  HASHIM '
60 REM                '
70 REM'''''''''''''''''
80 PLAY"T255;L64":CLEAR 50
90 DIM M(24,32):L=5
100 COLOR15,1,1:SCREEN3
110 OPEN"grp:"AS#1
120 COLOR15:PRESET(20,60):PRINT#1,"NIGHT":PRESET(24,60):PRINT#1,"NIGHT":COLOR6:PRESET(28,60):PRINT#1,"NIGHT"
130 COLOR15:PRESET(46,99):PRINT#1,"ESCAPE":COLOR15:PRESET(50,99):PRINT#1,"ESCAPE":COLOR6:PRESET(54,99):PRINT#1,"ESCAPE"
140 LINE(0,0)-(256,192),4,B:LINE(10,10)-(246,182),6,B
150 FOR X=1 TO 2000:NEXT X
160 GOTO 520
170 REM
180 K$=INKEY$
190 IF K$=" " THEN 180
200 IF K$="B" OR K$="b" THEN SCREEN0:COLOR 15,1,1:PRINT"DEV BREAK POINT :)":END
210 IF K$="L" OR K$="l" THEN 1310
220 IF K$<>CHR$(30) THEN 330
230 PR=PR-1
240 IF PR=1 THEN PR=1
250 REM
260 IF M(PR,PC)=0 THEN 480
270 IF M(PR,PC)=3 THEN 1370
280 PLAY"O4C"
290 PR=23
300 PUT SPRITE 1,((PC-1)*8,(PR-1)*8),4,1
310 GOTO 500
320 REM
330 IF K$<>CHR$(31) THEN 390
340 PR=PR+1
350 IF PR>24 THEN PR=24
360 REM
370 GOTO 260
380 REM
390 IF K$<>CHR$(28) THEN 440
400 PC=PC+1
410 IF PC>31 THEN PC=31
420 GOTO 440
430 REM
440 IF K$<>CHR$(29) THEN 480
450 PC=PC-1
460 IF PC<3 THEN PC=3
470 GOTO 260
480 PUT SPRITE 1,((PC-1)*8,(PR-1)*8),4,1
490 REM
500 RETURN
510 REM
520 R=RND(-TIME)
530 SCREEN 0,,0:KEY OFF:WIDTH 40
540 COLOR 15,1
550 CLS:PLAY"L32","L32","L32"
560 FORZ=1TO13:LOCATE Z,1:PRINT"NIGHT ESCAPE":FORB=1TO20:NEXTB:LOCATEZ,1:PRINT"            ":LOCATE 28-Z,1:PRINT"NIGHT ESCAPE":FOR B=1TO20:NEXTB:LOCATE 28-Z,1:PRINT"            ":ZA=Z+20:ZB=Z+30:PLAY"N=Z;","N=ZA;","N=ZB;"
570 NEXTZ:LIVES=3
580 LOCATE 13,1
590 PRINT"NIGHT ESCAPE":LOCATE 13,2:PRINT"============":LOCATE 18,4:PRINT"BY":LOCATE 12,6:PRINT"SHERIF<>HASHIM"
600 PR=16:L=5
610 PC=16
620 MR=4
630 MC=31
640 LOCATE1,10:PRINT"'I' FOR INSTRUCTIONS OR 'S' TO START":C$=INKEY$
650 IF C$="S" OR C$="s" THEN SK=1:GOTO 730
660 IF C$="I" OR C$="i" THEN GOTO 680
670 GOTO 640
680 LOCATE 0,10
690 PRINT"Massive dark night, blocks allover the street, you are trying to reach your home, but the orange monster is chasing you, you have 5 flash lights to use during each stage by pressing 'L' and move by the cursor keys,";
700 PRINT" watch the blocks scatter at the start of each stage carefully, your memory may be the only way if your 5 flash lights are used and u still didn't reach home, good luck :)"
710 C$=INKEY$:LOCATE10,22:PRINT"PRESS 'S' TO START":IF C$="S" OR C$="s" THEN 720 ELSE 710
720 SK=1
730 SCREEN 0:WIDTH40
740 COLOR 1,15,15
750 LOCATE 16,11:PRINT"STAGE ";SK:LOCATE 16,13:PRINT"LIVES ";LIVES:FORJ=1TO22:FORK=3TO32:M(J,K)=0:NEXT K,J
760 SCREEN1:COLOR1,15,15
770 REM
780 FOR K=1 TO 3
790 P$=" "
800 FOR J=0 TO 7
810 READ D$
820 P$=P$+CHR$(VAL("&H"+D$))
830 NEXT J
840 SPRITE$(K)=P$
850 NEXT K
860 DATA 38,44,38,7C,BA,38,44,C6
870 DATA F1,F2,F3,F4,F5,F6,F7,F8
880 DATA 1C,3E,6F,FF,77,07,7E,3C
890 FOR J=1 TO 8
900 READ D$
910 E1$=E1$+CHR$(VAL("&H"+D$))
920 READ D$
930 E2$=E2$+CHR$(VAL("&H"+D$))
940 NEXT J
950 DATA 1C,38,3E,7C,6F,F6,FF,FF
960 DATA 77,EE,07,E0,7E,7E,3C,3C
970 REM
980 FOR J=1 TO 22
990 FOR K=3 TO 32
1000 IF RND(1)< .9-SK/40 THEN 1060
1010 IF J=2 AND K=16 THEN 1060
1020 PLAY"L64"
1030 M(J,K)=1:V=J+30:PLAY"N=K;","N=J;","N=V;"
1040 LOCATE K-3,J-1:COLOR 1
1050 PRINT CHR$(219);
1060 NEXT K,J
1070 PUT SPRITE 2,(120,8),11,2
1080 M(2,16)=3
1090 LOCATE 13,2:COLOR 15
1100 PRINT CHR$(32)
1110 M(3,16)=0
1120 PUT SPRITE 1,((PC-1)*8,(PR-1)*8),4,1
1130 GOTO 1350
1140 GOSUB 180
1150 IF RND(1)>.3+SK/100 THEN 1140
1160 IF MC=PC THEN 1190
1170 MC=MC-1
1180 SPRITE$(3)=E1$
1190 IF MR<PR THEN 1210
1200 MR=MR-1
1210 IF MR=PR THEN 1230
1220 MR=MR+1
1230 IF MC>=PC THEN 1260
1240 SPRITE$(3)=E2$
1250 MC=MC+1
1260 PUT SPRITE 3,((MC-1)*8,(MR-1)*8),6,3
1270 PLAY"O3D"
1280 REM
1290 IF MR=PR AND MC=PC THEN 1430
1300 GOTO 1140
1310 L=L-1:IF L<=0THEN 1360
1320 COLOR 1,15,15:PLAY"L64O2CD","L64O4FG","L64O6AB"
1330 FOR DE=1 TO 50
1340 NEXT DE
1350 COLOR 1,1,1
1360 GOTO 1140
1370 PLAY"v14l16o3cdefgabo4cdefgabo5cdefgab","v14l32o4cdefgabo5cdefgabo6cdefgabo4cdefgabo5cdefgabo6cdefgab","v14l64o5cdefgabo6cdefgabo7cdefgabo5cdefgabo6cdefgabo7cdefgabo5cdefgabo6cdefgabo7cdefgabo5cdefgabo6cdefgabo7cdefgab":SCREEN0
1380 COLOR 1,15,15
1390 LOCATE 16,11:IF SK=9 THEN 1410
1400 PRINT "STAGE ";SK+1:LOCATE 16,13:PRINT"LIVES ";LIVES:FORJ=1TO22:FORK=3TO32:M(J,K)=0:NEXT K,J
1410 SK=SK+1:IF SK=10 THEN LOCATE 4,6:PRINT"C O N G R A T U L A T I O N S":LOCATE 4,7:PRINT"-----------------------------":LOCATE 9,9:PRINT"ALL STAGES CLEARED":FOR DF=1TO 10000:NEXTDF:RUN
1420 SCREEN1:COLOR1,15,15:CLS:PR=16:PC=16:MR=4:MC=31:L=5:GOTO970
1430 PLAY"T240;O3BAGFEDCO2BAGFEDC","T240;O5BAGFEDCO3BAGFEDC","T240;O7L64BAGFEDCO5L64BAGFEDCO7L64BAGFEDCO5L64BAGFEDC":LIVES=LIVES-1:IF LIVES=0 THEN 1450 ELSE 1440
1440 SCREEN0:COLOR1,15,15:LOCATE 16,11:PRINT"STAGE ";SK:LOCATE 16,13:PRINT"LIVES ";LIVES:FORJ=1TO22:FORK=3TO32:M(J,K)=0:NEXTK,J:SCREEN1:COLOR1,15,15:PR=16:PC=16:MR=4:MC=31:L=5:GOTO970
1450 SCREEN0:COLOR15,1,1:WIDTH40
1460 LOCATE 16,11
1470 PRINT "GAME OVER":FOR GO=1TO10:LOCATE 16,11:PRINT"GAME OVER":FORTY=1TO30:NEXTTY:LOCATE 16,11:PRINT"         ":FORTY=1TO50:NEXTTY:Z1=GO*2:Z2=GO*4:Z3=GO*8:PLAY"N=Z1;","N=Z2;","N=Z3;":NEXTGO
1480 REM'''''''''
1490 REM Code   '
1500 REM    End '
1510 REM'''''''''
1520 RUN
